AGS 3.3.3 - Errors while "Auto numbering speech lines..." [SOLVED]

[Cogliostro]

Okay, upgraded to AGS 3.3.2 and my problems playing music went away - I was getting static on MP3 files.  But when trying to number the lines for voice acting I got this error.  Upgraded to 3.3.3 and still getting the same error

ERROR when trying to number the lines for voice acting:

Code: ags

Unknown character name: ayer
Unterminated string in script: 'll just leave it where it is.");CntLabC++;}
Failed to save room room41.crm; details below
room41.asc(356): Error (line 356): Type mismatch: cannot convert 'const string' to 'int'

Code from the room itself ==This is the script for the ENTIRE ROOM so the line #s in the error code would match.

Code: ags

// room script file

// Create only a particles system manager
ParticleSystemManager PS;
int value=1;
bool Steam=true; 
bool Gas=false;
bool Rescue=false;
bool OpenDoor=false;
bool Mission=false;
bool DirtClean=true;
bool Turniquet=false;
bool TakeRope=false;

int CntFoot=0;
int CntPhilo=0;
int CntTanks=0;
int CntComp=0;
int count=1;
int CntRupt=0;
int CntChair=0;
int CntGloveT=0;
int CntGloveP=0;
int CntMask=0;
int CntLabC=0;

int s;  // PArticle Ssytem Identifier

// **********************************************************************
DynamicSprite* GenSprite;
DrawingSurface* GenSurf;
//oInv object must be created - has blank image = #105

function Take(int ImgNum) {
   int x=0;
   while (x<99) { 
     GenSprite = DynamicSprite.CreateFromExistingSprite(ImgNum, false);
     GenSprite.Resize(400 - (x*4), 400 - (x*4));
     GenSurf = GenSprite.GetDrawingSurface();
     GenSurf.DrawImage(0, 0, GenSprite.Graphic);
     oInv.Graphic = GenSprite.Graphic;
     oInv.X=(100 - x + GetViewportX());
     oInv.Y=400;  //oInv.Y=(400 - x*4 );
     Wait(1);
     if(x==0) { Wait(60); }
     x=x+5;
   }
   GenSurf.Release();
   GenSprite.Delete();
   oInv.Graphic = 105;
   oInv.X=0;
   oInv.Y=0;
}
// **********************************************************************

function Steamy() {
  s = PS.CreateSystem(100, false, dtBackground);  
  PS.emitter_creation_mode (s, rmAllways, 1, 2, 10);
  PS.emitter_set_position (s, ptPoint, 700.0, 235.0);
  PS.emitter_set_velocity (s, 120, 200, 60, 100);
  PS.emitter_set_transparency (s, 30, 85);
  PS.emitter_set_age (s, 40, 100);
  PS.emitter_set_sprite (s, 841, 844);
  PS.action_set_bound_box (s, 550, 0, 950, 400);
  PS.action_add_force (s, ftConstant, 0.0, 9.8);     
}

function Vapor()
{
  s = PS.CreateSystem(150, false, dtBackground);
  PS.emitter_creation_mode (s, rmAllways, 0, 1, 2);    
  PS.emitter_set_position (s, ptLine, 1290.0, 244.0, 1440.0, 244.0);
  PS.emitter_set_velocity (s, 10, 20, 278, 282);
  PS.emitter_set_transparency (s, 30, 90);
  PS.emitter_set_age (s, 300, 400);
  PS.emitter_set_sprite (s, 1547, 1550);    
  PS.action_set_bound_box (s, 1250, 0, 1490, 275); 
  
  PS.action_add_force (s, ftRandom, -2.0, 0.0, 2.0, 0.0);
  PS.action_set_transparency_evolution (s, 100, 7);
}

function room_Load()
{
  SetBackgroundFrame(0);
  oLeftDoor.SetView(112);
  oDoorRight.SetView(111);
  oOphidian.SetView(237);
  oOphidian.Animate(0, 2, eRepeat, eNoBlock);
  player.x=1;
  player.y=300;
  Steamy();
  player.ChangeView(11);
  player.SpeechView=12;
  oFoot.Transparency=80;
  
  oCoverUp.Clickable=false;
  oDirt.Visible=false;
  
  Hand=1;
  gTriforce.Visible=true;
  aSteam.Play();
}

function room_AfterFadeIn()
{
  StartCutscene(eSkipESCOnly);
  oLeftDoor.Animate(0, 1, eOnce, eBlock, eForwards);
  player.Walk(210, 340, eBlock, eAnywhere);
  oLeftDoor.Animate(0, 1, eOnce, eNoBlock, eBackwards);
  player.Say("&677 Medea mentioned radiation, so I took the precaution of changing into....");
  player.Walk(440, 340, eBlock, eAnywhere);
  player.Say("&678 IS THAT PHILO?!");
  EndCutscene();
}

function room_Leave()
{
  while (PS.num_systems) PS.DeleteLastSystem();
}

function hFloor_AnyClick()
{
  short TargetY=400;
  if (mouse.Mode==eModePointer) { player.Walk(mouse.x + GetViewportX(), mouse.y, eNoBlock, eWalkableAreas); }
  if (mouse.Mode==eModeCamera) { player.Say("&192 I don't need a picture of this."); }
  if (mouse.Mode==eModeXRay) { player.Say("&306 Not gonna be able to penetrate that with real x-rays, much less a terahertz scanner."); }
  if (mouse.Mode==eModeInternet) { player.Say("&307 It's not precisely an internet ready appliance."); }
  if (mouse.Mode==eModeFlashligh) { player.Say("&308 Running various bandwidths of UV light across the surface to look for either blood or bacteria... and nothing.");  }
  if (player.ActiveInventory==iDirt) {
    TargetY=mouse.y;
    if (TargetY < 270) TargetY=270;
    player.Walk(mouse.x + GetViewportX() + 20, TargetY + 20, eBlock, eWalkableAreas); 
    player.ChangeView(38); //STOOP
    player.Animate(0, 1, eOnce, eBlock, eForwards);    
    player.LoseInventory(iDirt);
    oDirt.X=player.x - 20;
    oDirt.Y=player.y - 20;
    oDirt.Visible=true;
    oDirt.Baseline=5;
    DirtClean=false;
    player.Animate(0, 2, eOnce, eBlock, eBackwards);  //STAND
    player.ChangeView(11);
    cCleaner.StopMoving();
  } 
}

function SavePhilo() 
{
  player.Say("&679 No time. I have to rescue Philo!");
}

function hDirt_AnyClick()
{
  if (!Rescue) SavePhilo();
  else { /********************************/
    if (SpotCount>0 && !Steam) {
      if (!player.HasInventory(iDirt)) { 
        player.Walk(740, 399, eBlock, eWalkableAreas);
        player.FaceLocation(660, 100, eBlock);
        player.ChangeView(38);
        player.Animate(0, 1, eOnce, eBlock, eForwards);
        player.Say("&680 I'll scoop up a handful.");
        player.AddInventory(iDirt);
        Take(1669);
        player.Animate(0, 2, eOnce, eBlock, eBackwards);
        player.ChangeView(11);
      } else { player.Say("&681 I already have some."); }
    } 
    
    if (SpotCount==0 && !Steam)
    {
      player.Say("&682 There's some dirt and debris on the floor.");
    }
    
    if (SpotCount==0 && Steam) 
    {
      player.Say("&683 Whatever it is, it's cold enough to cover me in frost bite, THOUGH THE SUIT!");  
    }
  } /***************************************/
}

function hValve_AnyClick()
{
  if (!Rescue) SavePhilo();
  else { /********************************/
    if (Steam) {
      player.Walk(640, 290, eBlock, eWalkableAreas);
      if (mouse.Mode==eModePointer) player.Say("&684 The valve is freezing cold!  I can't touch even with my suit on.");
      if (mouse.Mode==eModeCamera) { player.Say("&192 I don't need a picture of this."); }
      if (mouse.Mode==eModeXRay) { player.Say("&306 Not gonna be able to penetrate that with real x-rays, much less a terahertz scanner."); }
      if (mouse.Mode==eModeFlashligh) { player.Say("&308 Running various bandwidths of UV light across the surface to look for either blood or bacteria... and nothing.");  }
      if (mouse.Mode==eModeInternet)
      {
        PS.emitter_creation_mode (s, rmNumberOfTimes, 1, 1, 0);
        oFoot.TweenTransparency(0.60, 0, eEaseOutTween, eNoBlockTween);
        Wait(25);
        while (PS.num_systems) PS.DeleteLastSystem();
        cCleaner.ChangeRoom(41, 1440, 360);
        Steam=false;
        aSteam.Stop();
        aFutugreek.Play();
        Gas=true;      
        player.Say("&685 That did it!");
        Vapor();
      }
    } else {
      player.Say("&686 I am *NOT* going to reopen the valve.");
    }
  } /***************************************/
}

function region1_WalksOnto()
{
  if (Steam) {
    player.Walk(600, player.y, eBlock, eWalkableAreas);
    player.Say("&687 I'm *NOT* walking into the freezing exhaust.");
  }
}

function hExhaust_AnyClick()
{
  if (Steam)
  {
    player.Say("&688 Whatever it is, it's cold enough to give me instant frostbite, THOUGH THE SUIT!");    
  } else {
    hFloor_AnyClick();
  }
}

function hTanks_AnyClick()
{
  short Total=4;
  if (CntTanks%Total==0)  player.Say("&689 I have no idea what's in these tanks.");
  if (CntTanks%Total==1)  player.Say("&690 Normally I'd pull up any information I needed on these with my Visor, but now I have an actual Avatar and...  I don't seem to be able to read any more.");
  if (CntTanks%Total==2)  player.Say("&691 I can't read.  I'm illiterate?!  I have a Masters and a PhD, and I'm illiterate?  How much more screwed up can my life get?!");
  if (CntTanks%Total==3)  player.Say("&692 I really shouldn't mess with these unless it's ABSOLUTELY necessary.");
  CntTanks++;
}

function hComputer_AnyClick()
{
  if (!Rescue) SavePhilo();
  else { /********************************/  
    player.Walk(430, 300, eBlock, eWalkableAreas);
    player.FaceLocation(333, 0, eBlock);  
    short Total=5;  
    if (CntComp%Total==0) 
    {
      oSyn.SetView(5, 0, 0);
      oSyn.Visible=true;
      oSyn.Transparency=0;
      oSyn.SetPosition(GetViewportX(), 400);
      aSyn.Play();
      oSyn.Animate(0, 2, eOnce, eBlock, eForwards);
      int x = 0;
      while (x<=100) {
        oSyn.Transparency=x;
        x=x+10;
        Wait(1);
      }
      oSyn.SetPosition(0, 0);
      oSyn.Visible=false;
    }    
    if (CntComp%Total==1) 
    {
      player.Say("&693 With the Avatar installed in my head, the wiring across sections of my brain has created cross-communication where none should exist.");
      player.Say("&694 I think this is how it's manifesting for me.  When I try to read VR text, I get bombarded with other sensations.");
    }
    if (CntComp%Total==2) player.Say("&695 Mixed sensory signals is called synethesia.  It's the most common form of Ludwig's Disease.");
    if (CntComp%Total==3) player.Say("&696 It's impossible for me to read anymore.");
    if (CntComp%Total==4)
    {
      player.Say("&697 I'm illiterate.  I'm freakin' illiterate.");
      player.Say("&698 How screwed up is that?");
    }
    CntComp++;
  } /***************************************/
}

function oPhilo_AnyClick()
{
  if (!Rescue)
  {
    Rescue=true;
    player.Walk(610, 390, eBlock, eWalkableAreas);
    oPhilo.SetView(238, 0, 0);
    oPhilo.Animate(0, 4, eOnce, eNoBlock);
    player.Walk(525, 370, eBlock, eWalkableAreas);
    player.FaceLocation(700, 370, eBlock);
    player.StopMoving();
    player.ChangeView(105);
    oPhilo.Move(320, 390, 2, eNoBlock, eAnywhere);
    player.Walk(325, 370, eBlock, eWalkableAreas);
    oPhilo.Animate(1, 1, eOnce, eNoBlock);
    player.ChangeView(11);
    player.FaceLocation(player.x+200, player.y);
    player.Say("&699 He's missing a foot.");
  } else {
    if (player.ActiveInventory==iRope)
    {
       player.LoseInventory(iRope);
       player.Walk(480, 395, eBlock, eWalkableAreas);
       player.FaceLocation(410, 0, eBlock);
       player.StopMoving();
       player.ChangeView(38);
       player.Animate(0, 1, eOnce, eBlock, eForwards);
       Wait(20);
       oPhilo.Graphic=2345;
       player.Animate(0, 1, eOnce, eBlock, eBackwards);
       player.StopMoving();
       player.ChangeView(11);
       player.Say("&700 That should help.");
       Turniquet=true;  
    } else {
      short Total=4;
      if (CntPhilo%Total==0) player.Say("&701 That leg will eventually... ah... thaw.  When it does he could bleed to death.");
      if (CntPhilo%Total==1) player.Say("&702 The foot froze solid and broke off when I moved him.");
      if (CntPhilo%Total==2) player.Say("&703 At least he's alive.");
      if (CntPhilo%Total==3) player.Say("&704 Well, living with a regenerated limb beats the hell out of dying.");
      CntPhilo++;
    }
  }
}

function oFoot_AnyClick()
{
  short Total=4;
  player.FaceObject(oFoot);
  player.FaceLocation(700, 0);
  if (CntFoot%Total==0) player.Say("&705 It's Philoctetes' foot?!");
  if (CntFoot%Total==1) player.Say("&706 The freezing exhaust, just...  His foot broke off when I moved him.");
  if (CntFoot%Total==2) player.Say("&707 I am not touching that!  There's no point.  And it's really morbid.");
  if (CntFoot%Total==3) player.Say("&708 Losing your foot...  Ugh!");
  CntFoot++;
}

function oOphidian_AnyClick()
{
  hComputer_AnyClick();
}

function oDoorRight_AnyClick()
{
  if (Gas && !OpenDoor) { 
    oDoorRight.Animate(0, 1, eOnce, eBlock, eForwards);
    SetTimer(1, 160);
    OpenDoor=true;
    if (count==1) { 
      StartCutscene(eSkipESCOnly);'
      cHera.Say("There is a boric acid spill on the floor of engineering.");
      player.Say("How hazardous is it?");
      cHera.Say("It's non-toxic to humans, however, it will react violently with the fabric of your suit.");
      player.Say("And leave me vulnerable to radiation?");
      cHera.Say("Assuming you survive when the suit combusts, yes.");
      player.Say("Ah."&709 );
      EndCutscene();
    }
    if (count>1 && count<=3) cHera.Say("Please do not enter engineering.");
    if (count>3) player.Say("Maybe I could get SPOT to clean up the boric acid spill!");
  } else if (!Gas) {
    oDoorRight.Animate(0, 1, eOnce, eBlock, eForwards);
    player.Walk(1335, 250, eBlock, eAnywhere);
    if (Turniquet) 
    {
      oDoorRight.Animate(0, 1, eOnce, eBlock, eBackwards);
      player.ChangeRoom(10);
    } else { 
      player.Walk(1380, 350, eBlock, eAnywhere);
      player.Say("I can't just LEAVE Philoctetes?! There's got to be something I can do for him.");
      oDoorRight.Animate(0, 1, eOnce, eBlock, eBackwards);
    }
  }  
  count++;
}


function room_RepExec()
{
  if (OpenDoor && IsTimerExpired(1) && cCleaner.y>290) {
    OpenDoor=false;
    oDoorRight.Animate(0, 1, eOnce, eBlock, eBackwards);
  }
  
  // Random Cleaner Moving
  if (Gas) 
  {
    if (!cCleaner.Moving && DirtClean) {
      if (cCleaner.x<900) cCleaner.Walk(1240+Random(20), 350+Random(40), eNoBlock, eWalkableAreas);
      else cCleaner.Walk(730+Random(20), 370+Random(40), eNoBlock, eWalkableAreas);
    }
  }
  
  // Send Cleaner After the DIRT!
  if (!cCleaner.Moving && !DirtClean && !Mission) {
    cCleaner.Walk(oDirt.X, oDirt.Y, eNoBlock, eWalkableAreas);
    Mission=true;
    SetTimer(2, 3200);
  }
  
  //Dirt Finally cleaned up
  if (IsTimerExpired(2)) {
    oDirt.Visible=false;
    Mission=false;
    DirtClean=true;
  }
  
  // Cleaner in Engineering
  if (Mission  && OpenDoor && cCleaner.y<290) { 
    cCleaner.Move(1355, 250, eBlock, eWalkableAreas);
    aBlip.Play(); //Need better sound - More R2D2 - panicked little robot noise
    OpenDoor=false;
    Gas=false;
    oDoorRight.Animate(0, 1, eOnce, eBlock, eBackwards);
    oSpill.Visible=false;
    while (PS.num_systems) PS.DeleteLastSystem();
    SetBackgroundFrame(1);
    
    //A FEW MINUTES LATER
    oFewMin.Transparency=100;
    oFewMin.X=100+GetViewportX();
    oFewMin.Y=300;
    oFewMin.TweenTransparency(0.5, 0, eEaseInTween, eBlockTween);
    Wait(40);
    oFewMin.TweenTransparency(0.5, 100, eEaseOutTween, eBlockTween);
    oFewMin.Y=0;
    
    cHera.Say("The boric acid spill has been cleaned.  It is now safe to enter.");
    cCleaner.ChangeRoom(10, 619, 343);
  }
  if (Mission && !OpenDoor && cCleaner.y<290) { 
    aClunk.Play(); //Need better sound
    cCleaner.y=310;
  }
}

function hCoolant_AnyClick()
{  
  if (!Rescue) SavePhilo();
  else { /********************************/
    player.Say("It's the Ophidian Coolant System.  That much is obvious, and I assume it helps with the reactor.  So it's probably bad that it's damaged.");
    player.Say("However, I don't know anything about it.  So, I should use the computer station.");
    player.Say("And be extraordinarily cautious about it.");
  }
}

function region2_Standing()
{
  if (Gas) {
    if (!OpenDoor) { 
      oDoorRight.Animate(0, 1, eOnce, eBlock, eForwards);
      SetTimer(1, 160);
      OpenDoor=true;
    }
    player.Walk(1380, 350, eBlock, eAnywhere);
    player.Say("I really don't need to catch on fire.");
  } /*else {
    if (!Steam && !Turniquet) 
    {
      player.Walk(1380, 350, eBlock, eAnywhere);
      player.Say("I can't just LEAVE Philoctetes?! There's got to be somethimg I can do for him.");
    }    
  }*/
}

function hRupture_AnyClick()
{
  short Total=4;
  if (CntRupt%Total==0) player.Say("That is a serious looking rupture.");
  if (CntRupt%Total==1) player.Say("I'm not a nuclear engineer or anything, but I'm thinking that's the source of the problem.");
  if (CntRupt%Total==2) player.Say("Seriously, though, what happened?  How does a pipe just break like that?");
  if (CntRupt%Total==3) player.Say("How bad is it for the reactor when the cooling system is shut down?!");
  CntRupt++;
}

function hChair_AnyClick()
{
  short Total=4;
  if (CntChair%Total==0) player.Say("It's a chair.");
  if (CntChair%Total==1) player.Say("You sit on it and stuff.");
  if (CntChair%Total==2) player.Say("There's nothing on the chair or under it.");
  if (CntChair%Total==3) player.Say("What is wrong with me that I'm obsessing over a chair?!");
  CntChair++;
}

function hGloveTable_AnyClick()
{
  short Total=4;
  if (CntGloveT%Total==0) player.Say("It's the other work glove.");
  if (CntGloveT%Total==1) player.Say("They're made for working with freezing materials.");
  if (CntGloveT%Total==2) player.Say("If I took it, I would break up the set.");
  if (CntGloveT%Total==3) player.Say("Nah, I'll leave it where it is.");
  CntGloveT++;
}

function hGlovePipe_AnyClick()
{
  short Total=4;
  if (CntGloveP%Total==0) player.Say("There's a work glove stuck on top of that pipe.");
  if (CntGloveP%Total==1) player.Say("That would have been really handy a few minutes ago, but I did ok.");
  if (CntGloveP%Total==2) player.Say("I want to give it high five or something.");
  if (CntGloveP%Total==3) player.Say("Nah, I'll just leave it where it is.");
  CntGloveP++;
}

function hMask_AnyClick()
{
  short Total=4;
  if (CntMask%Total==0) player.Say("That's a full protective face mask.");
  if (CntMask%Total==1) player.Say("Probably part of the rest of the protective gear.");
  if (CntMask%Total==2) player.Say("Just a clear face mask.");
  if (CntMask%Total==3) player.Say("I really don't want it."&710 );
  CntMask++;
}

function hLabCoat_AnyClick()
{
  short Total=4;
  if (CntLabC%Total==0) player.Say("It's a lab coat.");
  if (CntLabC%Total==1) player.Say("It looks like there might be something in the pocket.");
  if (CntLabC%Total==2)
  {
    if (!TakeRope)
    {
      player.Say("Hey, there's a bit of green rope in there.  I think I know where to use this.");
      Take(2355);
      player.AddInventory(iRope);
    } else {
      player.Say("Nope."&711 );
    }
  }
  if (CntLabC%Total==3) player.Say("I'll just leave it where it is.");
  CntLabC++;
}

Clearly everything goes wrong starting with this line 356, but let me be clear, the automatic voice line number added &709 in the wrong spot, not me.  I can clear it out, try again and get the same error.  Whatever happened there threw a monkey wrench into the Auto line numbering and I can't figure out what it is.  Line 334 looks good, as does every line in between.

Any help would be greatly appreciated.

- Cogliostro

[Scavenger]

Line 350 has this typo:

Code: AGS

  StartCutscene(eSkipESCOnly);' //extraneous apostrophe

Could you remove it, clear out the &709 and try to do the auto-number lines again?

[Cogliostro]

SCAVENGER!

THAT WAS IT!  I could not find the freakin' apostrophe for love or money.  Thank you.


Good eyes...


- Cogliostro